• A private "field" variable that actually stores the data
• A published property definition that associates the property with the field

  Txyz = class(Twhatever)
  private
    FmyProperty : Integer ; // This defines the "Field" variable
                            // (That's why it starts with 'F')
  public
    constructor Create(AOwner: TComponent); override;
  published
    property myProperty : Integer read FmyProperty  write FmyProperty;
  end;

• The property can also be protected or public
• Both read and write are not required
• Instead of directly accessing the field variable, either read or write can reference a method
• And so forth

All properties should be assigned initial values in the component's overridden Create method.

  Txyz_WriteMode = (mcWM_Update, mcWM_Generate, mcWM_AddSection) ;

  Txyz = class(Twhatever)
  private
    FmyProperty : Txyz_WriteMode ; // This defines the "Field" variable
  published
    property myProperty : Txyz_WriteMode read FmyProperty  write FmyProperty;
  end;

Several components (such as TMemo and TRichEdit) have a property of this type. However ... because TStrings is an abstract class you can not CREATE a property of this type.

The secret (based on examining code and the help example for TStrings.Assign) is to define the property to be of type TStrings, but to create the property using TStringList (because it implements the TStrings abstract methods). Since the component creates the TStringList, be sure that it also Frees it. The other part of the secret is that you must Assign values to the property.

  Txyz = class(Twhatever)
  private
    FmyProperty  : TStrings;
    procedure SetmyProperty(Value: TStrings);
  public
    constructor Create(AOwner: TComponent); override;
    destructor  Destroy; override;
  published
    property myProperty : TStrings read FmyProperty write SetmyProperty;
  end;

constructor Txyz.Create(AOwner: TComponent);
begin
  inherited;
  FmyProperty := TStringList.Create; // Notice - not TStrings.Create !!
end;

destructor Txyz.Destroy;
begin
  FmyProperty.Free;   // Program leaks memory without this
  inherited;
end;   // Txyz.Destroy

procedure Txyz.SetmyProperty(Value: TStrings);
begin
  FmyProperty.Assign(Value);
end;

    property myProperty : TStrings read FmyProperty  write FmyProperty;

By default, TMemo sets the Text property default value and TRichEdit sets the Lines property default value to the name of the component, but I have not been able to figure out how that works.

TMouseEvent = procedure(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer) of object;

TControl = class(TComponent)
private
  FOnMouseDown: TMouseEvent;
protected
  procedure MouseDown(Button: TMouseButton; Shift: TShiftState;
    X, Y: Integer); dynamic;
  property OnMouseDown: TMouseEvent read FOnMouseDown write FOnMouseDown;
end;

procedure TControl.MouseDown(Button: TMouseButton;
                              Shift: TShiftState; X, Y: Integer);
begin
  if Assigned(FOnMouseDown) then 
        FOnMouseDown(Self, Button, Shift, X, Y);
end;

  procedure WMLButtonDown(var Message: TWMLButtonDown); message WM_LBUTTONDOWN;

procedure TCustomForm.DoHide;
begin
  if Assigned(FOnHide) then FOnHide(Self);
end;

From classes.pas

  TNotifyEvent = procedure(Sender: TObject) of object;

This is how it is defined.

    function  GetHeaderAsInteger(Name: string): Integer;
    procedure SetHeaderAsInteger(Name: string; const Value: Integer);

    property HeaderAsInteger[Name:string] : Integer read GetHeaderAsInteger
                                                   write SetHeaderAsInteger;

function TJCAMP.GetHeaderAsInteger(Name: string): Integer;
var
 s : string;
 i, code : integer;
begin
  s := FHeader.Values[Name];
  val(s, i, code);
  if code <> 0 then begin
     i := 0;
     if s='' then
       ErrorText := 'Not in header - ' + Name
     else
       ErrorText := 'Not an integer - ' + Name + ' = ' + s;
  end else begin
     ErrorText := '';
  end;
  result := i;
end;

procedure TJCAMP.SetHeaderAsInteger(Name: string; const Value: Integer);
var
 s : string;
begin
  s := IntToStr(Value);
  FHeader.Values[Name] := s;
end;

var
 i : integer;
begin
  JCAMP1.HeaderAsInteger['FindThis'] := 6;
  i := JCAMP1.HeaderAsInteger['FindThis'];
end;

// This is called when ErrorText is set
procedure TJCAMP.SetErrorText(const Value: String);
begin
  FErrorText := Value;
  if Value <> '' then begin
    if Assigned(OnConversionError) then OnConversionError(Self);
  end;
end;

  published
    property Line: TLineType read  FLine 
                             write SetLine default ltLeftToRight;

constructor TLine.Create(AOwner : TComponent);
begin
  inherited;
  line := ltLeftToRight;
end;

If the default directive is omitted, all values are stored in the *.dfm file. When present, if the property's value matches the default, it is not stored.

You can not use the default directive with strings. In this case, any string, except null (''), is automatically stored in the *.dfm file.

    // Without this test, the IDE exe (Delphi32.exe) is placed 
    // in the "Filename" property at design time
    // when you would prefer it to remain blank
  if  not (csDesigning in ComponentState) then
   if (Filename='') or (Filename='.') then begin
    s := Application.ExeName;
    Filename := ChangeFileExt(s, '.ini');
   end;

• When using a component, just place it on your form. (I'm still trying to figure out how to single step through it.)

• When developing the component, add the *.pas file to the current project via
  Project / Add to Project...
  This way
  • Changes to the source take effect immediately as soon as you re-compile the application
  • However, the design time performance does not change until you re-compile the *.dpk file.
    Note: This means that the property methods called by the Object Inspector do not change until the package is explicitly re-compiled.

URL: http:// cpcug.org / user / clemenzi / technical / Languages / Delphi / ComponentProperties.html