Delphi - JPEG Images

The standard TImage component can display jpeg images without any changes to your code IF you add jpeg to the uses clause. In a sample program, simply adding jpeg increased the exe size from 372K to 454K. Uh, if any included class definition has jpeg, then every TGraphic component has the capability.

Overview | Manipulating Pixels | Save bitmap as JPEG file | Bogus JPEG Error #36

Overview

TGraphic maintains a list of the supported graphics formats. When jpeg is added to a uses clause, it adds itself to the list. Because of how this works, it does not matter which source file contains the uses clause - if any file includes the jpeg unit, then every TGraphic will support it.

This is implemented via RegisterFileFormat which registers a new TGraphic class for use in LoadFromFile. You can then use the appropriate files with code similar to

SavePictureDialog1.Filter := GraphicFilter(TBitmap);
OpenDialog1.Filter        := GraphicFilter(TGraphic);

GraphicFilter(TGraphic) produces the following picklist format

All (*.jpg;*.jpeg;*.bmp;*.ico;*.emf;*.wmf)
JPEG Image File (*.jpg)
JPEG Image File (*.jpeg)
Bitmaps (*.bmp)
Icons (*.ico)
Enhanced Metafiles (*.emf)
Metafiles (*.wmf)

I was not able to find any other way to determine which file types are supported. The list used to store the registered types is private to Graphics.pas.

Manipulating Pixels

You can not directly manipulate (read or write) jpeg pixels. Instead, you must first copy the jpeg to a bitmap and then access the bitmap's pixels via its canvas. This code creates a TList of bitmaps made from jpegs.

var
  Form1:  TForm1;
  Images: TList;

procedure TForm1.Load_UIButtonClick(Sender: TObject);
var
 p1:TPicture;
 i:integer;
 str1, str2, str3:String;
 b1:TBitmap;
begin
  str1 :='E:\DelphiProjects\Images\Chab-01_';
  str3 := '.jpg';
  p1 := TPicture.Create;
  try
    images.Clear;

    for i := 1 to 9 do begin
      str2 := format('%2.2d', [i]);
      p1.LoadFromFile(str1+str2+str3); // E:\DelphiProjects\Images\Chab-01_03.JPG
      b1 := TBitmap.Create ;
      b1.Height := p1.Graphic.Height;  // Must set Height & Width
      b1.Width  := p1.Graphic.Width;
      b1.Canvas.Draw(0,0,p1.Graphic);
      images.Add(b1);
    end;

    Image1.Picture.Bitmap := b1;       // Just indicates that the loop is done

    Image_UIScrollBar.SetParams(1, 1, images.Count);
  finally
    p1.Free;
  end;
end;

This code fragment reads the bitmaps from the list and plots pixel values.

  b1:=(TBitmap(images.Items [0]));
  x1 := trunc(x * image2.Width  / b1.Width);
  y1 := trunc(y * image2.Height / b1.Height);
  Graph_x:= 1;
  Graph_y:= trunc((b1.Canvas.Pixels[x1, y1]and $ff)/4 +20 );

  image2.Canvas.Pen.Color := clRed ;
  image2.Canvas.MoveTo(Graph_x, Graph_y);
  for i :=1 to images.Count-1 do begin
    b1 := (TBitmap(images.Items [i]));
    Graph_x:= 10 + x_spacing*i;
    Graph_y:= b1.Canvas.Pixels[x1, y1] ;
    Graph_y:= trunc((Graph_y and $ff)/4 + 20);
    image2.Canvas.LineTo(Graph_x, Graph_y);
  end;

Reference: Converting a BMP to a JPEG and vice-versa under Delphi 3 - by Borland Developer Support Staff

Save bitmap as JPEG file

When reading a file, the TGraphic object inspects the file extension and creates the appropriate object type. Unfortunately, when writing a file, the extension is ignored. As a result, your code will have to do all the work.

The following example is strongly based on the help example for TJPEGImage.Assign (same as example for TGraphic.SaveToFile).

procedure Save_bitmap_as_jpeg_file_mc(bitmap: TBitmap; FileName: string);
var
  jp: TJpegImage;  //Requires the "jpeg" unit added to "uses" clause.
  ext : string;
begin
  ext := ExtractFileExt(FileName) ;
  if SameText(ext, '.jpg') or SameText(ext, '.jpeg') then begin

     // code from help "TGraphic.SaveToFile - Create, Assign, SaveToFile example"
    jp := TJpegImage.Create; // default quality = 90 out of 100
    try
      jp.Assign(Bitmap);
      jp.CompressionQuality := 100; // the maximum supported value
      jp.SaveToFile(FileName);
    finally
      jp.Free;
    end;
  end;
end;

I hard coded the CompressionQuality at 100% because I am using this to document screen images and I don't want any compression artifacts.

Bogus JPEG Error #36

Delphi provides jpeg support via the jpeg unit (jpeg.dcu) which is simply a wrapper for a library provided by the Independent JPEG Group (IJG).

When writing JPEG files larger than 1 mb, you may get the bogus

JPEG Error #36

"Output file write error --- out of disk space?"

and a zero byte file.

One fix is to modify JPEG.pas and recompile. With Delphi 5 professional, the source code is located on the CD at

D:\Info\Extras\Jpeg\JPEG.PAS

The problem is fixed by adding a try..except block and recompiling.

procedure TJPEGImage.Compress;

  try   // this is the fix
    jpeg_finish_compress(jc.c); // This line generates the error
  except
  end;

Note that jpeg_finish_compress is implemented in the library (it is external) and not written in Delphi.

Though several web pages say different, this problem was observed in Delphi 6.

Author: Robert Clemenzi